# gcc -nostdlib -nostdinc -Wl,--oformat,binary,-Ttext,0x100 a.s
	# MOV CS test 2
	# Examples on Atari Portfolio, 80C88
	# f6e4 3
	# 2c07 1
	# 5058 1
	# f6e42c07 2
	# f6e427 3
	# f6e490 2
	# f6e490909090 2
	# f6e49090909090 1
	# f6e440 2
	# f6e44040 2
	# f6e4404040 1
	# 37 1
	# 3737 2
	# 373737 3
	.code16
	mov	$st, %di
lp:	mov	$1, %ah
	int	$0x21
	sub	$'0', %al
	jb	done
	call	cv
	mov	$4, %cl
	shl	%cl, %al
	push	%ax
	mov	$1, %ah
	int	$0x21
	pop	%bx
	sub	$'0', %al
	jb	done
	call	cv
	or	%bl, %al
	cld
	stosb
	jmp	lp
done:	mov	$0xcb8e, %ax	# mov %bx, %cs
	cld
	stosw
	mov	$0x42, %al	# inc %dx
	mov	$0x10, %cx
	rep	stosb
	mov	$0xcb, %al	# lret
	mov	$0x10, %cl
	rep	stosb
	mov	$'0', %dl
	mov	%cs, %bx
	push	%bx
	mov	$1f, %cx
	push	%cx
	inc	%bx
	cli
	jmp	st
1:	sti
	mov	$2, %ah
	int	$0x21
	int	$0x20
cv:	test	$0x10, %al
	je	1f
	sub	$7, %al
1:	and	$0xf, %al
	ret
st:
